独闷闷网

标题: 51单片机汇编 [打印本页]
作者: 又一个暑假    时间: 2014-8-19 21:44
标题: 51单片机汇编
看到网上很多原创帖我很羡慕，嫉妒是不会，恨更不可能啦。只是很渴望有一天我也能在论坛发帖子来帮助别人。虽然没有没有鸿哥、朱老师等等的水平那么高，也没有文采，但是我还是把自己写的程序贴出来让高手们指教指教，欢迎拍砖，新手可以一起学习一起探讨。
作者: 又一个暑假    时间: 2014-8-19 21:48
本帖最后由 又一个暑假 于 2014-8-19 21:59 编辑

;/////////////////////////////////////////////////////////////////////////////////////////
;//矩阵键盘0—15按下按键显示对应的数值 ，没按之前显示"_"
;//
;////////////////////////////////////////////////////////////////////////////////////////
Key                            EQU     P3                ;矩阵键盘接的I/O口
key_state                   EQU                20H                ;用来标记消抖和防止多次触发
key_step_buffer         EQU                30H                ;消抖时键值的保存
key_step                    EQU                35H                ;存储键值
key_count                  EQU     36H                ;查表计数
        
        ORG         0000H
        SJMP        STAR
        ORG            1BH
        LJMP        Timer0_intrrupt  ;装T1中断服务程序
;/////////////////////////////////////////////////////////////////////////////////////////
;//初始化
;//
;////////////////////////////////////////////////////////////////////////////////////////
star:        
    mov  key_state,#00H
        mov  key_step,#00H
        mov  key_step_buffer,#00H
        mov  P0,#0ffH
        mov  P1,#0ffH
        mov  P2,#0aaH
        mov  IE,#088H  ;
        mov         TMOD,#010H
        mov         TH1, #0D8H
        mov         TL1, #0EFH
        setb TR1  ;启动T1
        setb EA
;/////////////////////////////////////////////////////////////////////////////////////////
;//主程序一直循环显示
;//
;////////////////////////////////////////////////////////////////////////////////////////        
loop:
          lcall keystep_disp            
          ljmp  loop
;/////////////////////////////////////////////////////////////////////////////////////////
;//键值显示程序
;//
;////////////////////////////////////////////////////////////////////////////////////////
keystep_disp:
                mov  a,key_step
                cjne a,#00H,keystep_disp_1   ;判断是否都没按过
                mov  P0,#0f7h      
                ret
keystep_disp_1:                        
                mov    key_count,#0ffH                  
                mov    dptr,#kcodtab                 
rk_none:                          
                clr    a
                movc   a,@a+dptr
                inc    dptr
                inc    key_count
                cjne   a,key_step,rk_none         ;按键查表                 
                mov    a, key_count
                mov    dptr,#segtab2
                movc   a,@a+dptr             ;数码管查表
                mov    p0,a
                lcall  delay        
                ret
;/////////////////////////////////////////////////////////////////////////////////////////
;//功能：按键扫描
;//方法：线反转法
;////////////////////////////////////////////////////////////////////////////////////////
key_check:
                mov  Key,#0f0H
                mov         a,Key
                cjne a,#0f0H,key_low
key_high:
                mov  key_state,#00H           ;没键按下，标志位清零
exit:
                ret
        
key_low:
                jb         key_state.0,key_unchange_1;有键按下判断是否抖动
                setb key_state.0
                mov  Key,#0f0H
                mov         a,Key
                orl  a,#0fH
                mov  Key,a
                mov  key_step_buffer,Key
                ret
                        
key_unchange_1:
                jb   key_state.1,exit        
                mov  Key,#0f0H
                mov  a,Key
                orl  a,#0fH
                mov  Key,a
                mov  a,Key
                cjne a,Key_step_buffer,key_high
                setb key_state.1            ;确定有键按下，自锁
                mov  key_step,Key_step_buffer
                ret
;/////////////////////////////////////////////////////////////////////////////////////////
;//Timer0中断服务程序
;//功能：定时扫描按键
;////////////////////////////////////////////////////////////////////////////////////////        
Timer0_intrrupt:      
                mov          TH1,#0D8H
                mov          TL1,#0EFH
                acall key_check                 ;检测按键
               
exit_interrupt:        
                reti
;/////////////////////////////////////////////////////////////////////////////////////////
;//延时子程序
;//
;////////////////////////////////////////////////////////////////////////////////////////        
delay:  mov   r3,#20
delay1: mov   r4,#50
        djnz  r4,$
        djnz  r3,delay1
        ret

;/////////////////////////////////////////////////////////////////////////////////////////
;//kcodtab 按键0——15对应的键值
;//segtab2 共阳数码管对应的0——9
;////////////////////////////////////////////////////////////////////////////////////////
kcodtab:
                db  11101110b,11011110b,10111110b,1111110b
                db  11101101b,11011101b,10111101b,1111101b
                db  11101011b,11011011b,10111011b,1111011b
                db  11100111b,11010111b,10110111b,1110111b
segtab2:                  
                db  0c0h,0f9h,0a4h,0b0h,099h,092h,082h,0f8h
                db  080h,090h,088h,083h,0c6h,0a1h,086h,08eh         
END


1.jpg (187.07 KB, 下载次数: 225)

1.jpg

矩阵键盘.rar

57.78 KB, 下载次数: 928
作者: xuan--lei    时间: 2014-8-19 21:57
汇编看看都难啊
作者: 又一个暑假    时间: 2014-8-19 22:01
xuan--lei 发表于 2014-8-19 21:57
汇编看看都难啊

我也是新手，一起努力！
作者: jianhong_wu    时间: 2014-8-19 23:39
感谢分享。努力加油。感谢你为论坛的付出。
作者: 不是盖的    时间: 2014-8-24 13:06
给点小建议，51汇编规范点写法，运行主函数之前先清理一下RAM的内存单元和配置一下堆栈指针，在C编程是这是启动代码做的事，帖主可参照51启动代码
作者: 又一个暑假    时间: 2014-8-24 14:32
不是盖的 发表于 2014-8-24 13:06
给点小建议，51汇编规范点写法，运行主函数之前先清理一下RAM的内存单元和配置一下堆栈指针，在C编程是这是 ...

多谢你的指导，以后请多多指教
作者: yao1318    时间: 2014-8-24 22:08
我刚学的时候就是看汇编的书很难看得进，后来看到大部份人都是用C语言和它有移植方便等优点就决定学C语言了，所以现在对汇编还是门外汉。
作者: 又一个暑假    时间: 2014-8-24 23:48
yao1318 发表于 2014-8-24 22:08
我刚学的时候就是看汇编的书很难看得进，后来看到大部份人都是用C语言和它有移植方便等优点就决定学C语言了 ...

我之前都是用C，现在想学汇编就利用51来学方便点，
作者: yao1318    时间: 2014-8-25 07:46
看来你可能是被台系的MCU的关系吧，我的一个工友也是这样。
作者: 又一个暑假    时间: 2015-3-31 16:24
  1. ;------------------------------------------------------------
  2. ；给大家分享个程序，网上看到的
  3. ORG 0040H
  4. AJMP MAIN
  5. MAIN:
  6. MOV P1,#0FFH
  7. MOV P2,#0FFH   ;初始化端口
  8. LOOP:
  9. CALL SREAD_KEY   ;读单按键--子程序
  10. MOV R0,KEY_NUM  

  12. CJNE R0,#00000010B,MAIN1 ;比较键值不等跳
  13.      CPL LED1_6.0   ;取反P2.0
  14. MAIN1:
  15. CJNE R0,#00000011B,MAIN2 ;比较键值不等跳
  16. CPL LED1_6.1   ;取反P2.1
  17. MAIN2:
  18. CJNE R0,#00000100B,MAIN3 ;比较键值不等跳
  19.      CPL LED1_6.2   ;取反P2.2
  20. MAIN3:
  21. CJNE R0,#00000101B,MAIN4 ;比较键值不等跳
  22. CPL LED1_6.3   ;取反P2.3
  23. MAIN4:
  24. CJNE R0,#00000110B,MAIN5 ;比较键值不等跳
  25. CPL LED1_6.4   ;取反P2.4
  26. MAIN5:
  27. CJNE R0,#00000111B,MAIN_EXIT ;比较键值不等跳
  28. CPL LED1_6.5   ;取反P2.5
  29. MAIN_EXIT:
  30. JMP LOOP
  31. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  32. ;读单按键--子程序
  33. ;子程序执行后返回值KEY_NUM即键值
  34. ;-----------------------------说明----------------------------
  35. ;短击:键按下时间<500MS
  36. ;长击:键按下时间>500MS
  37. ;两次按键间隔时间<700MS
  38. ;键值定义:
  39. ;KEY_NUM="00000000":  无键按下
  40. ;KEY_NUM="00000001":  无意义
  41. ;KEY_NUM="00000010":  单次短击
  42. ;KEY_NUM="00000011":  单次长击
  43. ;KEY_NUM="00000100":  短击+短击
  44. ;KEY_NUM="00000101":  短击+长击
  45. ;KEY_NUM="00000110":  长击+短击
  46. ;KEY_NUM="00000111":  长击+长击
  47. ;KEY_NUM="00001000":  短击+短击+短击
  48. ;KEY_NUM="00001001":  短击+短击+长击
  49. ;KEY_NUM="00001011":  短击+长击+长击
  50. ;KEY_NUM="00001111":  长击+长击+长击
  51. ;以编码从左看起第一个1看作为分界线，左边为0、而右边的0和1表示为：
  52. ;0短击1长击。
  53. ;以上组合已足够用了！
  54. ;*************************************************************
  55. ; KEY EQU P1.0
  56. ; KEY_NUM EQU 20H
  57. ;*************************************************************
  58. SREAD_KEY:
  59. MOV KEY_NUM,#00H ;键值清0
  60. JB KEY,SKEY_EXIT ;键未按下跳
  61. CALL DL10MS  ;延时去抖动
  62. JB KEY,SKEY_EXIT ;键未按下跳
  63. MOV KEY_NUM,#1  ;置键值为#00000001B
  64. SKEY_A:
  65. MOV R0,#00H  ;清计数器
  66. CLR C   ;清CY
  67. SKEY_B:
  68. CALL DL10MS
  69. INC R0
  70. MOV A,#50
  71. SUBB A,R0
  72. JC SKEY_C  ;当键按下>500MS跳
  73. JNB KEY,SKEY_B  ;键未释放跳
  74. CALL DL10MS  ;延时去抖动
  75. JNB KEY,SKEY_B  ;键未释放跳
  76. CLR C   ;CY置0
  77. JMP SKEY_D
  78. SKEY_C:
  79. JNB KEY,$  ;键未释放停
  80. CALL DL10MS  ;延时去抖动
  81. JNB KEY,$  ;键未释放停
  82. SETB C   ;CY置1
  83. SKEY_D:   
  84. MOV A,KEY_NUM
  85. RLC A   ;键值左移一位,C->键值低位
  86. MOV KEY_NUM,A
  87. JB KEY_NUM.2,SKEY_EXIT ;判断按键检测是否完成，完成跳
  88. ;说明：KEY_NUM.1时只判断单次按键两种组合，KEY_NUM.2时可判断两次按键4种组合+单次按键的2种组合=6种，以此类推。
  89. MOV R0,#00H  ;清计数器
  90. CLR C   ;CY置0
  91. SKEY_E:
  92. CALL DL10MS
  93. INC R0
  94. MOV A,#70
  95. SUBB A,R0
  96. JC SKEY_EXIT  ;当未按下>700MS跳出
  97. JB KEY,SKEY_E  ;键释放跳
  98. CALL DL10MS  ;延时去抖动
  99. JB KEY,SKEY_E  ;键释放跳
  100. JMP SKEY_A  ;当未按下<700MS再次检测
  101. SKEY_EXIT:
  102. RET
  103. ;************************************************************   
  104. ;延时10mS   
  105. ;************************************************************   
  106. DL10ms:
  107. MOV R5,#14H  ;20              ;10.262ms=20*511+2*20+1=20.261   
  108. TIME10MS_1:
  109. MOV R6,#0FFH  ;255    ;511us=255*2+1   
  110. DJNZ R6,$   
  111. DJNZ R5,TIME10MS_1   
  112. RET   
  113. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  114. END
复制代码
作者: 重庆-风雪    时间: 2015-3-31 21:32
感谢分享



欢迎光临 独闷闷网 (http://dumenmen.com/) Powered by Discuz! X3.2